Geschrieben von Shark am 07.12.2006 um 04:33:
Wow Macrothread
Dieser Thread ist gedacht um sinnvolle Macros für alle Klassen zu posten. Ich fange an indem ich grob erkläre was alles möglich ist.
1. /cast
/cast [<first set of options>] <first spellname>; [<second set of options>] <second spellname> ; [<third set of options>] <third spellname>; ...
help - Evaluates 'true' if target is friendly
harm - Evaluates 'true' if target is hostile
combat - Evaluates 'true' if you are in combat.
stance or stance:# - Evaluates 'true' if you are in a stance, or are in a particular stance (see below)
stealth - Evaluates 'true' if you are stealthed.
modifier or modifier:shift|ctrl|alt - Evaluates 'true' if the selected key is held down when the command is executed.
equipped:<item> - Evaluates 'true' if item is equipped. Item can be any valid inventory slot, item class or item subclass.
target=<unit> - Special option. It changes the target from the default of "target" to any valid unitid. (see below)
actionbar:<number> - Evaluates 'true' if the current actionbar is the same as the listed one.
pet:<pet type OR pet name> - Evaluates 'true' if the pet exists. Takes pet type (Owl, Bear, Imp) or pet name (Fluffy, MrBigglesworth). With no modifier (i.e. just [pet]) it evaluates 'true' if ANY pet exists.
mounted, swimming, flying - Evaluates 'true' if you are mounted, swimming, or flying, respectively.
indoors, outdoors - Evaluates 'true' if you are indoors or outdoors, respectively.
button:<#> - Evaluates 'true' if the selected button was used to 'click' the spell, defaults to 1 (see below).
channeling:<spell> - Evaluates true if you are channeling the spell listed. With no spell listed, it evaluates true if any spell is being channeled.
exists and dead - Evaluates true if your target is dead, or actually exists.
party - evaluates true if the target is a member of your party
raid - evaluates true if the target is a member of your party or raid
group - evaluates true if you are in a group
group:party/raid - evaluates true if you are in the specified type of group
-----------------------------------------------------------------------------------
Beispiele:
/cast [help] Flash Heal; Smite
Castet Flash heal wenn Target freundlich, ansonsten Smite.
/cast [target=player] Dispel Magic
Self-Dispel Macro (funktioniert auch mit Feind im Target).
/cast [nochanneling:Mind Flay] Mind Flay
Castet Mind Flay nur wenn es nicht bereits castet wird.
/cast [stealth] Ambush; Backstab
Castet Ambush in Stealth, sonst Backstab.
/cast [harm] Polymorph
/stopmacro [noharm]
Castet so lange Poly bis es sitzt (zum spammen).
/cast [pet:owl] Dive; [pet:cat] Dash; [pet] Growl
Castet verschiedene Abilities je nach Petart.
/cast [target=pet,dead] Revive Pet; [nopet] Call Pet; Mend Pet
Universal Petmacro für Hunter.
/cast [group:party] Arcane Brilliance; Arcane Intellect
Group/Single Int Buff je nachdem ob in Party oder nicht.
/stopcasting
/cast [target=player] Power Word: Shield
PWS auf sich selbst ohne Target zu verlieren.
/use Zandalarian Hero Charm
/stopcasting
/cast [target=player] Power Infusion
/stopcasting
/cast [target=player] Inner Focus
Powerup-Macro.
-----------------------------------------------------------------------------------
Stances:
Diese Info ist nicht sicher, angeblich gibt es Probs beim Warrior, einfach testen.
Class: Warrior Priest Druid Rogue
---------------------------------------------------------------
Stance:1 Battle Shadowform Bear Stealth
---------------------------------------------------------------
Stance:2 Defensive Aquatic
---------------------------------------------------------------
Stance:3 Berserker Cat
---------------------------------------------------------------
Stance:4 Travel
---------------------------------------------------------------
Stance:5 Moonkin/Tree
Beispiele:
/cast [nostance] Bear Form
Wechselt von Humanoid zum Bär.
/cast [nostance:3] Cat Form
Wechselt von Humanoid zur Katze.
/cast [stance:1] Overpower; Battle Stance
Wechselt in Battle Stance und castet Overpower, es sei denn man ist schon drin dann wird sofort Overpower gecastet.
/cast [stance:1] Overpower; [stance:2] Sunder Armor; [stance:3] Whirlwind
Krieger Spammbutton je nach Stance.
-----------------------------------------------------------------------------------
Items:
/cast [equipped:Two-Handed Swords] Mortal Strike; Heroic Strike
Castet MS mit Zweihand, HS mit Einhand.
/use [target=self] Heavy Runecloth Bandage
Selfcast für Bandagen, egal was im Target ist.
-----------------------------------------------------------------------------------
2. Castsequences
/castsequence [<options>] reset=<#>/target/combat/alt/shift/ctrl <spell1>, <spell2>, <spell3>
Castet eine Folge von Spells, es wird nur weitergegangen nach Erfolg, d.h. wenn ein Cast durch ist.
Beispiele:
/castsequence reset=24 Frost Nova, Blink
Castet erst Nova, dann Blink und macht Reset nach 24 Sekunden.
/castsequence reset=combat/target Cheap Shot, Sinister Strike, Gouge
Castet 3 Rogue Spells nacheinander, fängt neu an wenn sich Combatstatus oder Target ändert.
/castsequence reset=target Corruption, Immolate, Curse of Agony
Spammt 3 Dots mit einer Taste, resettet wenn sich Target ändert.
/castsequence reset=combat/target/shift Corruption, Immolate, Curse of Agony
Spammt 3 Dots, resettet bei Combat und Targetänderung oder wenn man Shift drückt.
-----------------------------------------------------------------------------------
3. Focus
/focus target
Legt Focus auf das aktuelle Target.
/cast [target=focus,exists] Polymorph
Castet Poly auf den zuvor mit /focus target festgelegten Gegner, auch wenn man jemanden anders im Target hat.
/cast [target=focus,exists] Flash Heal
Heilt den zuvor mit /focus target festgelegten Freund, auch wenn man jemanden anders im Target hat.